Antena Yagui de 12 dbi de ganancia

Antena Yagui de 12 dbi de ganancia

Este es un modelo de antena direccional y muy cómodo a la hora de manejarlo, debido a su pequeño tamaño.

El modelo original fue obtenido del foro de wireless de zero 13.

Planos

Patrón de radiación

Script TCL para generar el archovo nec (hacer click en la flecha)

#!/bin/sh
# \
exec tclsh "$0" "$@"
 
# Para entender como funciona es recomendable leer:
#
#   http://www.nec2.org/other/nec2prt3.pdf
#
 
set id_ultimo_segmento 0
 
# Escribe el registro con los comentarios de la antena.
proc generar_comentarios fd {
  puts $fd "CM Antena yagi (c) Montevideolibre http://montevideolibre.org"
  puts $fd "CM Este archivo se genera automáticamente desde yagi12.tcl"
  puts $fd "CE"
}
 
# Escribe el registro con la frecuencia en megahertz.
proc frecuencia {fd frecuencia} {
  puts $fd "FR 0 1 0 0 $frecuencia"
}
 
proc crear_barra {fd} {
  global id_ultimo_segmento
  set tag [incr id_ultimo_segmento]
  puts $fd "GW $tag 20 -100 0 -4.5 720 0 -4.5 3"
  return $tag
}
 
proc crear_chapa {fd} {
  set ancho 125.0
  set alto 75.0
  puts $fd "SP 0 1 -105 [expr $ancho/2] [expr $alto/2] -105 [expr $ancho/2] [expr -$alto/2]"
  puts $fd "SC 0 1 -105 [expr -$ancho/2] [expr -$alto/2] -105 [expr -$ancho/2] [expr $alto/2]"
}
 
# Devuelve el número de segmento
proc crear_dipolo {fd {estilo "doblado"} {h 0}} {
  global id_ultimo_segmento
  set tag [expr $id_ultimo_segmento+1]
  #l=122mm o sea, máximo 12.2. NS como mínimo longitud/0.1*l + 1
  # NS debería ser mayor a largo/12.2
 
  # cortamos el primero en 3 segmentos:
  # segmento cortado:"GW tag 10 0  28.2 -4.5  0 -28.2 -4.5"
 
  if {$estilo=="antena dklight"} {
    # tener imaginación: las tuplas del siguiente foreach punto_to, son de la
    # forma {x y z} ns, ns=número de segmentos.
    # X es siempre 0 porque decidimos poner el elemento activo en el plano X=0
    # Y es para un lado y el otro: ±(50-4)/2 = ±46/2 = ±23
    # Z es para arriba y abajo: ±(16.5-4)/2 = ±12.5/2 = ±6.25 ~= ±6
    # h es la altura que se le agrega al dipolo.
    foreach {y z ns} {
        5  6  -
       20  6  4
       23  2  2
       23 -2  2
       20 -6  2
      -20 -6  10
      -23 -2  2
      -23  2  2
      -20  6  2
       -1  6  4
        1  6  1
    } {
      set z [expr $z + $h]
      if {$ns=="-"} {
        set y_from $y
        set z_from $z
        continue
      }
      puts $fd "GW [incr id_ultimo_segmento] $ns 0 $y_from $z_from 0 $y $z 2"
      set y_from $y
      set z_from $z
    }
  }
  return $tag
}
 
proc activar_elemento {fd segmento} {
  puts $fd "EX 0 $segmento 1 00 1.0 0.0"
}
 
# Escala los segmentos dados previamente a milímetros
proc escalar_a_milimetros {fd} {
  puts $fd "GS 0 0 0.001"
}
 
# Termina la especificación geométrica de la antena e informa que
# no hay plano de tierra.
proc terminar_antena_sin_plano_de_tierra {fd} {
  puts $fd "GE 0"
}
 
# Ver en documentación: Extended thin wire kernel, cuando
# el radio de los segmentos es significativo:
proc extended_thin_wire_kernel {fd} {
  puts $fd "EK 0"
}
 
# Escribe el registro que finaliza la antena.
proc liquidar_archivo {fd} {
  puts $fd "EN"
}
 
proc crear_parásito {fd largo x} {
  global id_ultimo_segmento
  set tag [incr id_ultimo_segmento]
  set ns [expr int(2*$largo/12.2)]
  puts $fd "GW $tag $ns $x [expr -$largo/2.] 0 $x [expr $largo/2.] 0 1.5"
  return $tag
}
 
proc patrón_de_radiación {fd} {
  puts $fd "RP 0 72 72 1001 0.0 0.0 5.0 5.0 0 0"
}
 
proc sacar_tierra {fd} {
  puts $fd "GN -1"
}
 
# frecuencia por omisión 2437mhz
proc genera_antena {nombre_de_archivo {frecuencia 2412}} {
  # Abro el archivo de salida:
  set fd [open $nombre_de_archivo w]
  generar_comentarios $fd
 
  # Comienzo el modelado:
 
  # Crear elemento parásito de atrás
  crear_parásito $fd 60 -15
 
  # Crear parásitos de adelante
  set x 0
  # el centro primer parásito está a 36.5 - (11.5 + 4/2 + 3/2) del centro del
  # elemento activo, por eso está a 21.5.
  foreach {largo delta_x} {
    47.0  21.5
    47.0  27.5
    45.0  28.0
    44.8  27.0
    44.5  27.5
  } {
    set x [expr $x + $delta_x + 3]
    crear_parásito $fd $largo $x
  }
 
#FIXME de aquí en adelante:
 
  #set elemento_activo [crear_dipolo $fd doblado]
  #set elemento_activo [crear_dipolo $fd recto]
  #set elemento_activo [crear_dipolo $fd "bastante doblado"]
  set elemento_activo [crear_dipolo $fd "antena dklight" 6]
 
  #crear_barra $fd
  # Comento crear_chapa porque no influye
  #crear_chapa $fd
 
  escalar_a_milimetros $fd
  terminar_antena_sin_plano_de_tierra $fd
  # Fin del modelado.
 
  # El grosor de los segmentos de alambre es muy significativo.
  extended_thin_wire_kernel $fd
 
  activar_elemento $fd $elemento_activo
 
  sacar_tierra $fd
 
  frecuencia $fd $frecuencia
 
  patrón_de_radiación $fd
 
  liquidar_archivo $fd
  close $fd
}
 
genera_antena yagi12.nec

Archivo NEC generado (hacer click en la flecha)

CM Antena yagi (c) Montevideolibre http://montevideolibre.org
CM Este archivo se genera automáticamente desde yagi12.tcl
CE
GW 1 9 -15 -30.0 0 -15 30.0 0 1.5
GW 2 7 24.5 -23.5 0 24.5 23.5 0 1.5
GW 3 7 55.0 -23.5 0 55.0 23.5 0 1.5
GW 4 7 86.0 -22.5 0 86.0 22.5 0 1.5
GW 5 7 116.0 -22.4 0 116.0 22.4 0 1.5
GW 6 7 146.5 -22.25 0 146.5 22.25 0 1.5
GW 7 4 0 5 12 0 20 12 2
GW 8 2 0 20 12 0 23 8 2
GW 9 2 0 23 8 0 23 4 2
GW 10 2 0 23 4 0 20 0 2
GW 11 10 0 20 0 0 -20 0 2
GW 12 2 0 -20 0 0 -23 4 2
GW 13 2 0 -23 4 0 -23 8 2
GW 14 2 0 -23 8 0 -20 12 2
GW 15 4 0 -20 12 0 -1 12 2
GW 16 1 0 -1 12 0 1 12 2
GS 0 0 0.001
GE 0
EK 0
EX 0 7 1 00 1.0 0.0
GN -1
FR 0 1 0 0 2412
RP 0 72 72 1001 0.0 0.0 5.0 5.0 0 0
EN

Podés guardar el archivo anteriormente descrito como yagui12.nec, y abrirlo con qantenna

Construcción

Materiales

Cable monofilamento de 6mm (Eso es de sección, que es como se compra. De diámetro queda en aproximadamente 3mm)¹⁾
Ducto de PVC externo para cables eléctricos de 16mm
Conector del tipo deseado
Cemento epoxi, o acrílico (tipo la gotita)

Instrucciones de construcción

Corte los segmentos "parásito" del largo definido en el plano:
- uno de 60mm
- dos de 47mm
- uno de 45mm
- uno de 44,8mm
- uno de 44,5mm

El corte de los segmentos debe quedar cuadrado, y no en punta como cuando se realiza el corte con una pinza. Para dejar el corte cuadrado se puede utilizar una lima.

corte un alambre de largo suficiente para el elemento activo, pero no lo doble aún.
corte el caño de PVC de unos 25cm (es mejor que los 22 estipulados en el plano).
marcar con un lápiz una línea recta de extremo a extremo del caño, y otra exactamente del lado opuesto.
marcar el primer punto sobre la línea, a unos 20mm del extremo del caño.
marcar los sucesivos puntos, teniendo en cuenta que las medidas proporcionadas en el plano son internas. Habrá que tomar la medida desde los extremos del punto, que debería tener unos 3mm ²⁾.
repetir el paso anterior sobre la línea opuesta
perforar el caño en los puntos de ambos lados, utilizando un taladro con una mecha de 1mm
agrandar los orificios con la ayuda de un alambre igual al utilizado para los segmentos, pero cortado en punta con una pinza. Esto logrará que los segmentos entren justos.
colocar en orden los segmentos de forma centrada.
colocar el alambre que conformará el elemento activo.
darle la forma deseada según el plano.
cortar los sobrantes del alambre del elemento activo, y limarlos para que queden cuadrados.
centrar todos los elementos parásito, y el elemento activo, y pegarlos
encintar el cable y soldar malla y núcleo a los extremos del elemento activo

Fotos

¹⁾ si no se encuentra se puede utilizar cable de 3mm de sección, que da unos 2mm de diámetro

²⁾ o 2mm si es el alambre que se está utilizando

manuales/antena_yagui_12.txt · Última modificación: 2008/07/21 20:03 por dklight